e5aa65a630
Import the parameter types from openstacklib::policy so that parameter types are validated at module level, instead of internal resource call. Also remove the tag which is no longer necessary after dependency refactoring. Change-Id: I44f80c0fdcd3333df0548dfb13e474ef26d8c617 Signed-off-by: Takashi Kajinami <kajinamit@oss.nttdata.com>
84 lines
2.5 KiB
Puppet
84 lines
2.5 KiB
Puppet
# == Class: octavia::policy
|
|
#
|
|
# Configure the octavia policies
|
|
#
|
|
# === Parameters
|
|
#
|
|
# [*enforce_scope*]
|
|
# (Optional) Whether or not to enforce scope when evaluating policies.
|
|
# Defaults to $facts['os_service_default'].
|
|
#
|
|
# [*enforce_new_defaults*]
|
|
# (Optional) Whether or not to use old deprecated defaults when evaluating
|
|
# policies.
|
|
# Defaults to $facts['os_service_default'].
|
|
#
|
|
# [*policies*]
|
|
# (Optional) Set of policies to configure for octavia
|
|
# Example :
|
|
# {
|
|
# 'octavia-context_is_admin' => {
|
|
# 'key' => 'context_is_admin',
|
|
# 'value' => 'true'
|
|
# },
|
|
# 'octavia-default' => {
|
|
# 'key' => 'default',
|
|
# 'value' => 'rule:admin_or_owner'
|
|
# }
|
|
# }
|
|
# Defaults to empty hash.
|
|
#
|
|
# [*policy_path*]
|
|
# (Optional) Path to the octavia policy.yaml file
|
|
# Defaults to /etc/octavia/policy.yaml
|
|
#
|
|
# [*policy_default_rule*]
|
|
# (Optional) Default rule. Enforced when a requested rule is not found.
|
|
# Defaults to $facts['os_service_default'].
|
|
#
|
|
# [*policy_dirs*]
|
|
# (Optional) Path to the octavia policy folder
|
|
# Defaults to $facts['os_service_default']
|
|
#
|
|
# [*purge_config*]
|
|
# (optional) Whether to set only the specified policy rules in the policy
|
|
# file.
|
|
# Defaults to false.
|
|
#
|
|
class octavia::policy (
|
|
$enforce_scope = $facts['os_service_default'],
|
|
$enforce_new_defaults = $facts['os_service_default'],
|
|
Openstacklib::Policies $policies = {},
|
|
Stdlib::Absolutepath $policy_path = '/etc/octavia/policy.yaml',
|
|
$policy_default_rule = $facts['os_service_default'],
|
|
$policy_dirs = $facts['os_service_default'],
|
|
Boolean $purge_config = false,
|
|
) {
|
|
include octavia::deps
|
|
include octavia::params
|
|
|
|
$policy_parameters = {
|
|
policies => $policies,
|
|
policy_path => $policy_path,
|
|
file_user => 'root',
|
|
file_group => $octavia::params::group,
|
|
file_format => 'yaml',
|
|
purge_config => $purge_config,
|
|
}
|
|
|
|
create_resources('openstacklib::policy', { $policy_path => $policy_parameters })
|
|
|
|
# policy config should occur in the config block also.
|
|
Anchor['octavia::config::begin']
|
|
-> Openstacklib::Policy[$policy_path]
|
|
-> Anchor['octavia::config::end']
|
|
|
|
oslo::policy { 'octavia_config':
|
|
enforce_scope => $enforce_scope,
|
|
enforce_new_defaults => $enforce_new_defaults,
|
|
policy_file => $policy_path,
|
|
policy_default_rule => $policy_default_rule,
|
|
policy_dirs => $policy_dirs,
|
|
}
|
|
}
|