37049a867d
... because the latest lint no longer allows usage of legacy facts and top scope fact. Change-Id: Ia9ab733a7fc5cbb5b23659ff7cbfd3b2b7d2fb18
96 lines
2.8 KiB
Puppet
96 lines
2.8 KiB
Puppet
# == Class: gnocchi::policy
|
|
#
|
|
# Configure the gnocchi policies
|
|
#
|
|
# === Parameters
|
|
#
|
|
# [*enforce_scope*]
|
|
# (Optional) Whether or not to enforce scope when evaluating policies.
|
|
# Defaults to $facts['os_service_default'].
|
|
#
|
|
# [*enforce_new_defaults*]
|
|
# (Optional) Whether or not to use old deprecated defaults when evaluating
|
|
# policies.
|
|
# Defaults to $facts['os_service_default'].
|
|
#
|
|
# [*policies*]
|
|
# (Optional) Set of policies to configure for gnocchi
|
|
# Example :
|
|
# {
|
|
# 'gnocchi-context_is_admin' => {
|
|
# 'key' => 'context_is_admin',
|
|
# 'value' => 'true'
|
|
# },
|
|
# 'gnocchi-default' => {
|
|
# 'key' => 'default',
|
|
# 'value' => 'rule:admin_or_owner'
|
|
# }
|
|
# }
|
|
# Defaults to empty hash.
|
|
#
|
|
# [*policy_path*]
|
|
# (Optional) Path to the gnocchi policy.yaml file
|
|
# Defaults to /etc/gnocchi/policy.yaml
|
|
#
|
|
# [*policy_default_rule*]
|
|
# (Optional) Default rule. Enforced when a requested rule is not found.
|
|
# Defaults to $facts['os_service_default'].
|
|
#
|
|
# [*policy_dirs*]
|
|
# (Optional) Path to the gnocchi policy folder
|
|
# Defaults to $facts['os_service_default']
|
|
#
|
|
# [*purge_config*]
|
|
# (optional) Whether to set only the specified policy rules in the policy
|
|
# file.
|
|
# Defaults to false.
|
|
#
|
|
class gnocchi::policy (
|
|
$enforce_scope = $facts['os_service_default'],
|
|
$enforce_new_defaults = $facts['os_service_default'],
|
|
$policies = {},
|
|
$policy_path = '/etc/gnocchi/policy.yaml',
|
|
$policy_default_rule = $facts['os_service_default'],
|
|
$policy_dirs = $facts['os_service_default'],
|
|
$purge_config = false,
|
|
) {
|
|
|
|
include gnocchi::deps
|
|
include gnocchi::params
|
|
|
|
validate_legacy(Hash, 'validate_hash', $policies)
|
|
|
|
if ! $purge_config {
|
|
# TODO(tkajinam): Remove this once version with policy-in-code implementation
|
|
# is released.
|
|
exec { 'gnocci-oslopolicy-convert-json-to-yaml':
|
|
command => "oslopolicy-convert-json-to-yaml --namespace gnocchi --policy-file /etc/gnocchi/policy.json --output-file ${policy_path}",
|
|
unless => "test -f ${policy_path}",
|
|
path => ['/bin','/usr/bin','/usr/local/bin'],
|
|
require => Anchor['gnocchi::install::end'],
|
|
}
|
|
Exec<| title == 'gnocchi-oslopolicy-convert-json-to-yaml' |>
|
|
-> File<| title == $policy_path |>
|
|
}
|
|
|
|
$policy_parameters = {
|
|
policies => $policies,
|
|
policy_path => $policy_path,
|
|
file_user => 'root',
|
|
file_group => $::gnocchi::params::group,
|
|
file_format => 'yaml',
|
|
purge_config => $purge_config,
|
|
}
|
|
|
|
create_resources('openstacklib::policy', { $policy_path => $policy_parameters })
|
|
|
|
oslo::policy { 'gnocchi_config':
|
|
enforce_scope => $enforce_scope,
|
|
enforce_new_defaults => $enforce_new_defaults,
|
|
policy_file => $policy_path,
|
|
policy_default_rule => $policy_default_rule,
|
|
policy_dirs => $policy_dirs,
|
|
}
|
|
|
|
}
|