1856384e07
Import the parameter types from openstacklib::policy so that parameter types are validated at module level, instead of internal resource call. Change-Id: I8a164df8648d71ed03ca2a0ee91b0ddb8f95c90d Signed-off-by: Takashi Kajinami <kajinamit@oss.nttdata.com>
84 lines
2.4 KiB
Puppet
84 lines
2.4 KiB
Puppet
# == Class: cinder::policy
|
|
#
|
|
# Configure the cinder policies
|
|
#
|
|
# === Parameters
|
|
#
|
|
# [*enforce_scope*]
|
|
# (Optional) Whether or not to enforce scope when evaluating policies.
|
|
# Defaults to $facts['os_service_default'].
|
|
#
|
|
# [*enforce_new_defaults*]
|
|
# (Optional) Whether or not to use old deprecated defaults when evaluating
|
|
# policies.
|
|
# Defaults to $facts['os_service_default'].
|
|
#
|
|
# [*policies*]
|
|
# (Optional) Set of policies to configure for cinder
|
|
# Example :
|
|
# {
|
|
# 'cinder-context_is_admin' => {
|
|
# 'key' => 'context_is_admin',
|
|
# 'value' => 'true'
|
|
# },
|
|
# 'cinder-default' => {
|
|
# 'key' => 'default',
|
|
# 'value' => 'rule:admin_or_owner'
|
|
# }
|
|
# }
|
|
# Defaults to empty hash.
|
|
#
|
|
# [*policy_path*]
|
|
# (Optional) Path to the cinder policy.yaml file
|
|
# Defaults to /etc/cinder/policy.yaml
|
|
#
|
|
# [*policy_default_rule*]
|
|
# (Optional) Default rule. Enforced when a requested rule is not found.
|
|
# Defaults to $facts['os_service_default'].
|
|
#
|
|
# [*policy_dirs*]
|
|
# (Optional) Path to the cinder policy folder
|
|
# Defaults to $facts['os_service_default']
|
|
#
|
|
# [*purge_config*]
|
|
# (optional) Whether to set only the specified policy rules in the policy
|
|
# file.
|
|
# Defaults to false.
|
|
#
|
|
class cinder::policy (
|
|
$enforce_scope = $facts['os_service_default'],
|
|
$enforce_new_defaults = $facts['os_service_default'],
|
|
Openstacklib::Policies $policies = {},
|
|
Stdlib::Absolutepath $policy_path = '/etc/cinder/policy.yaml',
|
|
$policy_default_rule = $facts['os_service_default'],
|
|
$policy_dirs = $facts['os_service_default'],
|
|
Boolean $purge_config = false,
|
|
) {
|
|
include cinder::deps
|
|
include cinder::params
|
|
|
|
$policy_parameters = {
|
|
policies => $policies,
|
|
policy_path => $policy_path,
|
|
file_user => 'root',
|
|
file_group => $cinder::params::group,
|
|
file_format => 'yaml',
|
|
purge_config => $purge_config,
|
|
}
|
|
|
|
create_resources('openstacklib::policy', { $policy_path => $policy_parameters })
|
|
|
|
# policy config should occur in the config block also.
|
|
Anchor['cinder::config::begin']
|
|
-> Openstacklib::Policy[$policy_path]
|
|
-> Anchor['cinder::config::end']
|
|
|
|
oslo::policy { 'cinder_config':
|
|
enforce_scope => $enforce_scope,
|
|
enforce_new_defaults => $enforce_new_defaults,
|
|
policy_file => $policy_path,
|
|
policy_default_rule => $policy_default_rule,
|
|
policy_dirs => $policy_dirs,
|
|
}
|
|
}
|