579de28ae9
The minimum version of puppetlabs-stdlib has been bumped globally, so now we can use the common type definition. Change-Id: Iac803296f72a57707d57a48a3b54718e60b4285e Signed-off-by: Takashi Kajinami <kajinamit@oss.nttdata.com>
70 lines
1.9 KiB
Puppet
70 lines
1.9 KiB
Puppet
# Installs the aodh notifier service
|
|
#
|
|
# == Params
|
|
# [*enabled*]
|
|
# (optional) Should the service be enabled.
|
|
# Defaults to true.
|
|
#
|
|
# [*manage_service*]
|
|
# (optional) Whether the service should be managed by Puppet.
|
|
# Defaults to true.
|
|
#
|
|
# [*package_ensure*]
|
|
# (optional) ensure state for package.
|
|
# Defaults to 'present'
|
|
#
|
|
# [*workers*]
|
|
# (optional) Number of workers for notifier service.
|
|
# Defaults to $facts['os_workers'].
|
|
#
|
|
# [*batch_size*]
|
|
# (optional) Number of notification messages to wait before dispatching
|
|
# them.
|
|
# Defaults to $facts['os_service_default'].
|
|
#
|
|
# [*batch_timeout*]
|
|
# (optional) Number of seconds to wait before dispatching samples when
|
|
# batch_size is not reached.
|
|
# Defaults to $facts['os_service_default']
|
|
#
|
|
class aodh::notifier (
|
|
Boolean $manage_service = true,
|
|
Boolean $enabled = true,
|
|
Stdlib::Ensure::Package $package_ensure = 'present',
|
|
$workers = $facts['os_workers'],
|
|
$batch_size = $facts['os_service_default'],
|
|
$batch_timeout = $facts['os_service_default'],
|
|
) {
|
|
include aodh::deps
|
|
include aodh::params
|
|
|
|
aodh_config {
|
|
'notifier/workers': value => $workers;
|
|
'notifier/batch_size': value => $batch_size;
|
|
'notifier/batch_timeout': value => $batch_timeout;
|
|
}
|
|
|
|
package { 'aodh-notifier':
|
|
ensure => $package_ensure,
|
|
name => $aodh::params::notifier_package_name,
|
|
tag => ['openstack', 'aodh-package'],
|
|
}
|
|
|
|
if $manage_service {
|
|
if $enabled {
|
|
$service_ensure = 'running'
|
|
} else {
|
|
$service_ensure = 'stopped'
|
|
}
|
|
|
|
service { 'aodh-notifier':
|
|
ensure => $service_ensure,
|
|
name => $aodh::params::notifier_service_name,
|
|
enable => $enabled,
|
|
hasstatus => true,
|
|
hasrestart => true,
|
|
tag => 'aodh-service',
|
|
}
|
|
}
|
|
}
|